'**************************************
    ' Name: Directory Listing/Detailing Scri
    '     pt
    ' Description:Have you ever had the need
    '     to print out an extremely lengthy direct
    '     ory? There's a way to do it through MS-D
    '     OS, but why not have a way to do it thro
    '     ugh Windows? The code segment below will
    '     list the details of a directory and save
    '     the results in to a text file. Try it on
    '     a legthy directory like the C:\Windows o
    '     r C:\Winnt\ directory. You can view the 
    '     text file and even print it (of course).
    '     Excellent tool when archiving files or i
    '     f you just want to view what's on your h
    '     ard drive. Hope you enjoy it.
    ' By: Sean Street
    '
    ' Inputs:One command line argument indic
    '     ating the directory to detail. If comman
    '     d-line argument is omitted, then the use
    '     r is prompted to provide the location vi
    '     a an Inputbox.
    '
    ' Returns:A text file named "dir<fold
    '     er name>.txt"
    '
    'This code is copyrighted and has    ' limited warranties.Please see http://w
    '     ww.Planet-Source-Code.com/vb/scripts/Sho
    '     wCode.asp?txtCodeId=6593&lngWId=4    'for details.    '**************************************
    
    Dim fso, strPath, fsoFolder, fsoTextFile, strTemp, strData, fsoFile, strFile
    Set fso = CreateObject("Scripting.FileSystemObject")
    strPath = "?"
    if WScript.Arguments.Count > 0 Then strPath = WScript.Arguments(0)
    Do While Not fso.FolderExists(strPath)
    	strPath = InputBox ("Enter the directory to detail:","Directory Lister" )
    	if Len(strPath) = 0 Then WScript.Quit
    Loop
    Set fsoFolder = fso.GetFolder(strPath)
    strFile = "dir" & fsoFolder.Name & ".txt"
    strTemp = Left(WScript.ScriptFullName,Len(WScript.ScriptFullName) - Len(WScript.ScriptName))
    Set fsoTextFile = fso.openTextFile(strTemp & strFile, 2, True)
    fsoTextFile.WriteLine "Directory information for: " & strPath
    fsoTextFile.WriteBlankLines(1)
    strData = "File Name" & String(16," ")
    strData = strData & "Size" & String(4," ")
    strData = strData & "Date Modified "
    strData = strData & "File Type"
    fsoTextFile.WriteLine (strData)
    fsoTextFile.WriteBlankLines(1)
    For Each fsoFile In fsoFolder.Files
    	if fsoFile.Name <> strFile AND fsoFile.Name <> WScript.ScriptName Then
    		strTemp = Left(fsoFile.Name,24)
    		strData = strTemp & String(25-Len(strTemp)," ")
    		strTemp = CLng(fsoFile.Size / 1024) & " KB"
    		strData = strData & strTemp & String(8-Len(strTemp)," ")
    		strTemp = Month(fsoFile.DateLastModified) & "/" & Day(fsoFile.DateLastModified) & "/" & Year(fsoFile.DateLastModified)
    		strData = strData & strTemp & String(15-Len(strTemp)," ") & fsoFile.Type
    		fsoTextFile.WriteLine (strData)
    	End if
    Next
    WScript.Echo "Detailing For directory " & strPath & " is complete. The results are in the file named " & strFile
    WScript.Quit