'**************************************
    ' Name: Paging Function
    ' Description:This routine will create p
    '     aging links for you. It automates the li
    '     nks for you, just pass the current page,
    '     the total amount of pages to it and it w
    '     ill do the rest.
    ' By: Shannon Harmon
    '
    'This code is copyrighted and has    ' limited warranties.Please see http://w
    '     ww.Planet-Source-Code.com/vb/scripts/Sho
    '     wCode.asp?txtCodeId=6875&lngWId=4    'for details.    '**************************************
    
    <%
    Public function Paging(ByVal intPage, ByVal intPageCount, ByVal intRecordCount)
    	'Customize me to your liking...
    	'Assumes that the paging request variable is named 'page'
    	Dim strQueryString
    	Dim strScript
    	Dim intStart
    	Dim intEnd
    	Dim strRet
    	Dim i
    	if intPage > intPageCount Then
    		intPage = intPageCount
    	ElseIf intPage < 1 Then 
    		intPage = 1
    	End if
    	
    	if intRecordCount = 0 Then
    		strRet = "No Records Found"
    	ElseIf intPageCount = 1 Then
    		strRet = "All Records Shown"
    	Else
    		For i = 1 To Request.QueryString.Count
    			if LCase(Request.QueryString.Key(i)) <> "page" Then
    				strQueryString = strQueryString & "&" 
    				strQueryString = strQueryString & Server.URLEncode(Request.QueryString.Key(i)) & "=" 
    				strQueryString = strQueryString & Server.URLEncode(Request.QueryString.Item(i))
    			End if
    		Next
    		For i = 1 To Request.Form.Count
    			if LCase(Request.Form.Key(i)) <> "page" Then
    				strQueryString = strQueryString & "&" 
    				strQueryString = strQueryString & Server.URLEncode(Request.Form.Key(i)) & "=" 
    				strQueryString = strQueryString & Server.URLEncode(Request.Form.Item(i))
    			End if
    		Next
    		if Len(strQueryString) <> 0 Then
    			strQueryString = "?" & Mid(strQueryString, 2) & "&"
    		Else
    			strQueryString = "?"
    		End if
    		strScript = Request.ServerVariables("SCRIPT_NAME") & strQueryString
    	
    		if intPage <= 10 Then
    			intStart = 1
    		Else
    			if (intPage Mod 10) = 0 Then
    				intStart = intPage - 9
    			Else
    				intStart = intPage - (intPage Mod 10) + 1
    			End if
    		End if
    		intEnd = intStart + 9
    		if intEnd > intPageCount Then intEnd = intPageCount
    	
    		strRet = "Page " & intPage & " of " & intPageCount & ": "
    	
    		if intPage <> 1 Then 
    			strRet = strRet & "<A href=""" & strScript
    			strRet = strRet & "page=" & intPage - 1 
    			strRet = strRet & """><<PREv</A> "
    		End if
    	
    		For i = intStart To intEnd
    			if i = intPage Then
    				strRet = strRet & "<B>" & i & "</B> "
    			Else
    				strRet = strRet & "<A href=""" & strScript
    				strRet = strRet & "page=" & i 
    				strRet = strRet & """>" & i & "</A>"
    				if i <> intEnd Then strRet = strRet & " "
    			End if
    		Next
    	
    		if intPage <> intPageCount Then
    			strRet = strRet & " <A href=""" & strScript
    			strRet = strRet & "page=" & intPage + 1 
    			strRet = strRet & """>Next>></A> "
    		End if
    	End if
    	
    	Paging = strRet
    End function
    'Test the function, input values would n
    '     ormally
    'be pulled from database recordset infor
    '     mation
    Dim intPage
    intPage = 1
    if Not IsEmpty(Request("page")) Then
    	if IsNumeric(Request("page")) Then
    		intPage = CLng(Request("page"))
    	End if
    End if
    Response.Write Paging(intPage, 25, 200)
    %>